Project Structure

• MetaCreateTable.dpr
• MetaCreateTableForm.pas
• MetaCreateTableForm.dfm {FormMetaCreateTable}

program MetaCreateTable;

uses
  Forms,
  MetaCreateTableForm in 'MetaCreateTableForm.pas' {FormMetaCreateTable};

{$R *.res}

begin
  Application.Initialize;
  Application.MainFormOnTaskbar := True;
  Application.CreateForm(TFormMetaCreateTable, FormMetaCreateTable);
  Application.Run;
end.

   unit MetaCreateTableForm;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, DB, DBXDataExpressMetaDataProvider,
  DBXInterbase, WideStrings, SqlExpr;

type
  TFormMetaCreateTable = class(TForm)
    btnCreate: TButton;
    SqlConnection1: TSQLConnection;
    edTableName: TEdit;
    btnTableListOld: TButton;
    btnTableListMeta: TButton;
    MemoLog: TMemo;
    btnColumnsList: TButton;
    procedure btnCreateClick(Sender: TObject);
    procedure btnTableListOldClick(Sender: TObject);
    procedure btnTableListMetaClick(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure btnColumnsListClick(Sender: TObject);
  private
    metaProv: TDBXDataExpressMetaDataProvider;
  public
    procedure InitMetaProvider;
    procedure Log (const strMsg: string);
    { Public declarations }
  end;

var
  FormMetaCreateTable: TFormMetaCreateTable;

implementation

uses
  DBXCommon, DBXMetaDataProvider, DBXCommonTable, DBXTypedTableStorage;

{$R *.dfm}

procedure TFormMetaCreateTable.btnColumnsListClick(Sender: TObject);
var
  dbxTable: TDBXColumnsTableStorage;
begin
  InitMetaProvider;

  dbxTable := metaProv.GetCollection (
    TDBXMetaDataCommands.GetColumns + ' ' + edTableName.Text)
    as TDBXColumnsTableStorage;
  while dbxTable.Next do
    Log (dbxTable.ColumnName +
      ' [' + dbxTable.TypeName + ']');
end;

procedure TFormMetaCreateTable.btnCreateClick(Sender: TObject);
var
  MetaDataTable: TDBXMetaDataTable;
begin
  InitMetaProvider;

  MetaDataTable := TDBXMetaDataTable.Create;
  MetaDataTable.TableName := edTableName.Text;
  MetaDataTable.AddColumn(TDBXInt32Column.Create('id'));
  MetaDataTable.AddColumn(TDBXDecimalColumn.Create('amount', 10, 2));
  MetaDataTable.AddColumn(TDBXUnicodeCharColumn.Create('city', 32));

  metaProv.QuoteIdentifierIfNeeded('');
  metaProv.CreateTable(MetaDataTable);
  Log ('Table ' + MetaDataTable.TableName + ' created');
end;

procedure TFormMetaCreateTable.btnTableListMetaClick(Sender: TObject);
var
  dbxTable: TDBXTablesTableStorage;
begin
  InitMetaProvider;

  dbxTable := metaProv.GetCollection (
    TDBXMetaDataCommands.GetTables) as TDBXTablesTableStorage;
  while dbxTable.Next do
    if not (dbxTable.TableType = 'SYSTEM TABLE') then
      Log (dbxTable.TableName);
end;

procedure TFormMetaCreateTable.btnTableListOldClick(Sender: TObject);
var
  sl: TStringList;
  str: string;
begin
  sl := TStringList.Create;
  try
    SqlConnection1.GetTableNames(sl);
    for str in sl do
    begin
      Log (str);
    end;
  finally
    sl.Free;
  end;
end;

procedure TFormMetaCreateTable.FormCreate(Sender: TObject);
begin
  SqlConnection1.Open;
end;

procedure TFormMetaCreateTable.InitMetaProvider;
begin
  if not Assigned (metaProv) then
  begin
    metaProv := TDBXDataExpressMetaDataProvider.Create;
    metaProv.Connection := SqlConnection1.DBXConnection;
    metaProv.Open;
  end;
end;

procedure TFormMetaCreateTable.Log(const strMsg: string);
begin
  MemoLog.Lines.Add (strMsg);
end;

end.

object FormMetaCreateTable: TFormMetaCreateTable
  Left = 0
  Top = 0
  Caption = 'MetaCreateTable'
  ClientHeight = 292
  ClientWidth = 554
  Color = clBtnFace
  Font.Charset = DEFAULT_CHARSET
  Font.Color = clWindowText
  Font.Height = -11
  Font.Name = 'Tahoma'
  Font.Style = []
  OldCreateOrder = False
  OnCreate = FormCreate
  PixelsPerInch = 96
  TextHeight = 13
  object btnCreate: TButton
    Left = 24
    Top = 24
    Width = 115
    Height = 25
    Caption = 'btnCreate'
    TabOrder = 0
    OnClick = btnCreateClick
  end
  object edTableName: TEdit
    Left = 152
    Top = 26
    Width = 185
    Height = 21
    TabOrder = 1
    Text = 'NewTableName'
  end
  object btnTableListOld: TButton
    Left = 24
    Top = 62
    Width = 115
    Height = 25
    Caption = 'btnTableListOld'
    TabOrder = 2
    OnClick = btnTableListOldClick
  end
  object btnTableListMeta: TButton
    Left = 24
    Top = 104
    Width = 115
    Height = 25
    Caption = 'btnTableListMeta'
    TabOrder = 3
    OnClick = btnTableListMetaClick
  end
  object MemoLog: TMemo
    Left = 152
    Top = 64
    Width = 394
    Height = 220
    TabOrder = 4
  end
  object btnColumnsList: TButton
    Left = 24
    Top = 144
    Width = 115
    Height = 25
    Caption = 'btnColumnsList'
    TabOrder = 5
    OnClick = btnColumnsListClick
  end
  object SqlConnection1: TSQLConnection
    ConnectionName = 'IBCONNECTION'
    DriverName = 'Interbase'
    GetDriverFunc = 'getSQLDriverINTERBASE'
    LibraryName = 'dbxint.dll'
    LoginPrompt = False
    Params.Strings = (
      'DriverName=Interbase'

              'Database=C:\Program Files\Common Files\CodeGear Shared\Data\Empl' +
        'oyee.GDB'
      'RoleName=RoleName'
      'User_Name=sysdba'
      'Password=masterkey'
      'ServerCharSet='
      'SQLDialect=3'
      'ErrorResourceFile='
      'LocaleCode=0000'
      'BlobSize=-1'
      'CommitRetain=False'
      'WaitOnLocks=True'
      'Interbase TransIsolation=ReadCommited')
    VendorLib = 'gds32.dll'
    Left = 18
    Top = 18
  end
end